8 hours ago
(This post was last modified: 8 hours ago by Borje Hagsten.)
A bit of sunday fun and maybe even useful to someone. 
Eventual discussion here: https://pump.richheimer.de/showthread.php?tid=166
![[Image: oKGiyLF.jpg]](https://iili.io/oKGiyLF.jpg)

Eventual discussion here: https://pump.richheimer.de/showthread.php?tid=166
![[Image: oKGiyLF.jpg]](https://iili.io/oKGiyLF.jpg)
Code:
'======================================================================
' pbColors.bas
' Extracted a color dialog I have been using in my own code editor for
' many years. It has 4 Tab pages with PB RGB Equates, System Colors,
' QB colors and the 48 Basic colors presented in Windows Color dialog
' plus access to the ComCtrl32 dialog itself. It also includes a
' "Color Dropper" to enable detecting any color, anywhere on screen
' and the option of setting it to "Always on Top" on screen. Use and
' abuse as you like. Public Domain by Borje Hagsten November 2026.
'
' Tab page 1 - 140 built-in PB RGB Equates
' Tab Page 2 - 30 system colors (may change depending on system settings)
' Tab Page 3 - 16 QB colors. QuickBASIC's old DOS/EGA-colors (0–15).. :)
' Tab Page 4 - 48 Basic colors and access to all 16,777,216 colors via Display Color
' Textboxes shows selected color, etc. and enable quick copy & paste.
' Not so many comments, but simple enough to use and follow code, I hope..
'======================================================================
#COMPILE EXE
#DIM ALL
'#RESOURCE MANIFEST, 1, "xptheme.xml" '<- if you have a manifest file.
'--------------------------------------------------------------------
%UNICODE = 1
#INCLUDE "WIN32API.INC"
#INCLUDE "UxTheme.inc"
'--------------------------------------------------------------------
' For old/new dialog design - thank you Jules Marchildon for this tip!
DECLARE FUNCTION DwmSetWindowAttribute LIB "dwmapi.dll" ALIAS "DwmSetWindowAttribute" _
(BYVAL hWnd AS DWORD,BYVAL dwAttribute AS DWORD, _
BYREF pvAttribute AS DWORD, BYVAL cbAttribute AS DWORD) AS LONG
%DWMWA_NCRENDERING_POLICY = 2 '-Set, who should draw the frame
%DWMNCRP_DISABLED = 1 '-DWM does not draw the frame gives the legacy look
%DWMNCRP_ENABLED = 2 '-DWM draws the modern frame
'--------------------------------------------------------------------
%IDC_LABEL1 = 501
%IDC_LABEL2 = 502
%IDC_LABEL3 = 503
%IDC_LABEL4 = 504
%IDC_LBL_START = 505
%IDC_LBL_ZOOM = 506
%IDC_LBL_SHOW = 507
%IDC_BTN_COLOR = 520
%IDC_LISTBOX1 = 531
%IDC_TEXTBOX1 = 541
%IDC_TEXTBOX2 = 542
%IDC_TEXTBOX3 = 543
%IDC_TAB = 561
%IDC_CHK_ONTOP = 581
TYPE custcolors
clr(15) AS DWORD
END TYPE
TYPE cData
wzCol AS WSTRING * 8
wzEqu AS WSTRINGZ * 32
END TYPE
GLOBAL tSysCol() AS cData
GLOBAL tPBcol() AS cData
GLOBAL tQBcol() AS cData
GLOBAL tBasCol() AS cData
GLOBAL ghDlg, ghListBox, ghListBox2, ghListBox3, ghListBox4 AS DWORD
GLOBAL hTab1, hTab2, hTab3, hTab4, gfColor AS LONG
'======================================================================
' Program entrance
'----------------------------------------------------------------------
FUNCTION PBMAIN () AS LONG
LOCAL c, fNum AS LONG, dwStyle AS DWORD
LOCAL rc AS RECT, wStr AS WSTRING
SetProcessDPIAware ' I do this, because I use 150% screen scaling
DIALOG DEFAULT FONT "Tahoma", 9
DIALOG NEW 0, "pbColors",,, 196, 252, %WS_CAPTION OR %WS_SYSMENU OR _
%WS_MINIMIZEBOX, 0 TO ghDlg
' I like the old windows design better
DwmSetWindowAttribute ghDlg, %DWMWA_NCRENDERING_POLICY, %DWMNCRP_DISABLED, 4
DIALOG SET COLOR ghDlg, -1, %LTGRAY
'------------------------------------------------------------------
CONTROL ADD TAB, ghDlg, %IDC_TAB, "", 5, 5, 185, 162, _
%WS_CHILD OR %WS_VISIBLE OR %WS_TABSTOP OR %TCS_OWNERDRAWFIXED
TAB INSERT PAGE ghDlg, %IDC_TAB, 1, 0, "PB Equates" CALL TabProc1 TO hTab1
TAB INSERT PAGE ghDlg, %IDC_TAB, 2, 0, "System colors" CALL TabProc2 TO hTab2
TAB INSERT PAGE ghDlg, %IDC_TAB, 3, 0, "QB colors" CALL TabProc3 TO hTab3
TAB INSERT PAGE ghDlg, %IDC_TAB, 4, 0, "Basic colors" CALL TabProc4 TO hTab4
SetWindowTheme(GetDlgItem(ghDlg, %IDC_TAB), " ", " ")
'------------------------------------------------------------------
' add an ownerdrawn ListBox on each Tab Page
dwStyle = %WS_CHILD OR %WS_VISIBLE OR %WS_TABSTOP OR _
%WS_VSCROLL OR %LBS_NODATA OR %LBS_NOTIFY OR _
%LBS_NOINTEGRALHEIGHT OR %LBS_OWNERDRAWFIXED
CONTROL ADD LISTBOX, hTab1, %IDC_LISTBOX1, , 1, 1, 179, 147, dwStyle, %WS_EX_CLIENTEDGE
CONTROL HANDLE hTab1, %IDC_LISTBOX1 TO ghListBox
SetWindowTheme(ghListBox, " ", " ")
CONTROL SEND hTab1, %IDC_LISTBOX1, %LB_GETITEMHEIGHT, 0, 0 TO c 'Get height of line
CONTROL SEND hTab1, %IDC_LISTBOX1, %LB_SETITEMHEIGHT, 0, c * 2
SetPbColorArray
CONTROL SEND hTab1, %IDC_LISTBOX1, %LB_SETCOUNT, UBOUND(tPbCol), 0
'------------------------------------------------------------------
CONTROL ADD LISTBOX, hTab2, %IDC_LISTBOX1, , 1, 1, 179, 147, dwStyle, %WS_EX_CLIENTEDGE
CONTROL HANDLE hTab2, %IDC_LISTBOX1 TO ghListBox2
SetWindowTheme(ghListBox2, " ", " ")
CONTROL SEND hTab2, %IDC_LISTBOX1, %LB_SETITEMHEIGHT, 0, c * 2
SetSysColorArray
CONTROL SEND hTab2, %IDC_LISTBOX1, %LB_SETCOUNT, UBOUND(tSysCol), 0
'------------------------------------------------------------------
CONTROL ADD LISTBOX, hTab3, %IDC_LISTBOX1, , 1, 1, 179, 147, dwStyle, %WS_EX_CLIENTEDGE
CONTROL HANDLE hTab3, %IDC_LISTBOX1 TO ghListBox3
SetWindowTheme(GetDlgItem(hTab3, %IDC_LISTBOX1), " ", " ")
CONTROL SEND hTab3, %IDC_LISTBOX1, %LB_SETITEMHEIGHT, 0, c * 2
SetQbColorArray
CONTROL SEND hTab3, %IDC_LISTBOX1, %LB_SETCOUNT, UBOUND(tQbCol), 0
'------------------------------------------------------------------
' Page 4 LB is special - we use multicolumn feature for gridlike looks
CONTROL ADD LISTBOX, hTab4, %IDC_LISTBOX1,, 1, 1, 179, 127, dwStyle OR _
%LBS_MULTICOLUMN, %WS_EX_CLIENTEDGE
CONTROL HANDLE hTab2, %IDC_LISTBOX1 TO ghListBox4
' if manifest for ComCtl32.dll v6, turn off Theme for better 3D looks..
SetWindowTheme(GetDlgItem(hTab4, %IDC_LISTBOX1), " ", " ")
GetClientRect(ghListBox4, rc)
CONTROL SEND hTab4, %IDC_LISTBOX1, %LB_SETITEMHEIGHT, 0, rc.nBottom/7.0 'set new to adjust
CONTROL SEND hTab4, %IDC_LISTBOX1, %LB_SETHORIZONTALEXTENT, 417, 0 'want horizontal scrollbar?
CONTROL SEND hTab4, %IDC_LISTBOX1, %LB_SETCOLUMNWIDTH, rc.nRight/7.6 , 0 'set column width
SetBasColorArray
CONTROL SEND hTab4, %IDC_LISTBOX1, %LB_SETCOUNT, 48, 0
CONTROL ADD BUTTON, hTab4, %IDC_BTN_COLOR, "Color Dlg", 127, 131, 50, 14
CONTROL ADD LABEL, hTab4, %IDC_LABEL4, "", 2, 130, 120, 17, %SS_SUNKEN
'------------------------------------------------------------------
CONTROL ADD LABEL, ghDlg, %IDC_LABEL1, "Equate:", 5, 171, 30, 12
CONTROL SET COLOR ghDlg, %IDC_LABEL1, -1, %LTGRAY
CONTROL ADD TEXTBOX, ghDlg, %IDC_TEXTBOX1, "", 35, 170, 155, 12, %ES_READONLY OR %ES_CENTER, %WS_EX_CLIENTEDGE
SetWindowTheme(GetDlgItem(ghDlg, %IDC_TEXTBOX1), " ", " ")
CONTROL ADD LABEL, ghDlg, %IDC_LABEL2, "RGB:", 5, 186, 30, 12
CONTROL SET COLOR ghDlg, %IDC_LABEL2, -1, %LTGRAY
CONTROL ADD TEXTBOX, ghDlg, %IDC_TEXTBOX2, "", 35, 185, 77, 12, %ES_READONLY OR %ES_CENTER, %WS_EX_CLIENTEDGE
SetWindowTheme(GetDlgItem(ghDlg, %IDC_TEXTBOX2), " ", " ")
CONTROL ADD LABEL, ghDlg, %IDC_LABEL3, "BGR:", 120, 186, 20, 12
CONTROL SET COLOR ghDlg, %IDC_LABEL3, -1, %LTGRAY
CONTROL ADD TEXTBOX, ghDlg, %IDC_TEXTBOX3, "", 142, 185, 47, 12, %ES_READONLY OR %ES_CENTER, %WS_EX_CLIENTEDGE
SetWindowTheme(GetDlgItem(ghDlg, %IDC_TEXTBOX3), " ", " ")
'-------------------------------------------------------------------
CONTROL ADD FRAME, ghDlg, 1234, " Color Dropper ", 5, 200, 185, 47
CONTROL SET COLOR ghDlg, 1234, -1, %LTGRAY
SetWindowTheme(GetDlgItem(ghDlg, 1234), " ", " ")
wStr = "Click here to start" + $CRLF + _
"Move cursor to target"
CONTROL ADD LABEL, ghDlg, %IDC_LBL_START, wStr, 11, 210, 90, 21, _
%WS_CHILD OR %WS_VISIBLE OR %SS_CENTER OR %SS_NOTIFY OR %SS_SUNKEN
CONTROL SET COLOR ghDlg, %IDC_LBL_START, %BLUE, RGB(250, 235, 166)
CONTROL ADD LABEL, ghDlg, %IDC_LBL_SHOW, "", 107, 210, 35, 31, _
%WS_CHILD OR %WS_VISIBLE OR %SS_NOTIFY OR %SS_SUNKEN
CONTROL ADD LABEL, ghDlg, %IDC_LBL_ZOOM, "", 148, 210, 35, 31, _
%WS_CHILD OR %WS_VISIBLE OR %SS_NOTIFY OR %SS_SUNKEN
'-------------------------------------------------------------------
CONTROL ADD CHECKBOX, ghDlg, %IDC_CHK_ONTOP, "Always on top ", 11, 233, 60, 12
CONTROL SET COLOR ghDlg, %IDC_CHK_ONTOP, -1, %LTGRAY
CONTROL SET CHECK ghDlg, %IDC_CHK_ONTOP, 1
'-------------------------------------------------------------------
DIALOG SHOW MODELESS ghDlg, CALL DlgProc
DO
DIALOG DOEVENTS
LOOP WHILE ISWIN(ghDlg)
END FUNCTION
'======================================================================
' Main Dialog procedure
'----------------------------------------------------------------------
CALLBACK FUNCTION DlgProc() AS LONG
LOCAL wStr AS WSTRING, pt AS POINTAPI
LOCAL r, g, b AS BYTE, lRes AS LONG
STATIC hBrushBk, hBrushFr AS DWORD
STATIC hDC AS DWORD, iCol, StartDrag AS LONG
SELECT CASE CB.MSG
CASE %WM_INITDIALOG
gfColor = -1
hBrushBk = CreateSolidBrush(%LTGRAY) ' create a few brushes
hBrushFr = CreateSolidBrush(%WHITE)
SetWindowPos CB.HNDL, %HWND_TOPMOST, 0, 0, 0, 0, %SWP_NOMOVE OR %SWP_NOSIZE
CASE %WM_DESTROY
IF hBrushBk THEN DeleteObject hBrushBk ' delete what we created
IF hBrushFr THEN DeleteObject hBrushFr
CASE %WM_SYSCOLORCHANGE ' update the tSysCol array if system colors are changed
CALL SetSysColorArray
CASE %WM_DRAWITEM
LOCAL hBrush, hPen AS DWORD, rc, rc2 AS RECT
LOCAL lpdis AS DRAWITEMSTRUCT PTR, wzTxt AS WSTRINGZ * 100
IF CB.WPARAM = %IDC_TAB THEN ' This is where ownerdrawn tab control is drawn
lpDis = CB.LPARAM
IF @lpDis.ItemState = %ODS_SELECTED THEN ' If tab page is selected,
FillRect @lpDis.hDC, @lpDis.rcItem, hBrushFr ' paint tab button with %Page_Color
SetTextColor (@lpDis.hDc, %BLUE) ' with blue text
ELSE
GetClientRect(@lpDis.hwndItem, rc) ' get entire tab control rect
rc.nBottom = 2 ' paint top 2 lines
FillRect @lpDis.hDC, rc, hBrushBk ' with dialog color (%Dlg_Color)
TabCtrl_GetItemRect(@lpDis.hwndItem, _ ' get last tab button rect
TabCtrl_GetItemCount(@lpDis.hwndItem)-1, rc2)
IF rc2.nRight < rc.nRight THEN ' if it ends beföre total width
rc.nLeft = rc2.nRight ' set up to paint area right of last button
rc.nBottom = rc2.nBottom ' and above tab page
FillRect @lpDis.hDC, rc, hBrushBk ' with dialog color (%Dlg_Color)
END IF
SetTextColor (@lpDis.hDc, GetSysColor(%COLOR_WINDOWTEXT)) ' black text on non-selected page buttons
END IF
TAB GET TEXT CB.HNDL, %IDC_TAB, @lpDis.ItemId + 1 TO wzTxt ' grab text (it's ownerdrawn)
SetBkMode (@lpDis.hDc, %TRANSPARENT) ' set transparent baclground
DrawText @lpDis.hDc, BYCOPY wzTxt, LEN(wzTxt), @lpDis.rcItem, _ ' and draw text centered/vcentered
%DT_SINGLELINE OR %DT_CENTER OR %DT_VCENTER
END IF
CASE %WM_COMMAND
SELECT CASE CB.CTL
CASE %IDC_CHK_ONTOP
IF CBCTLMSG = %BN_CLICKED THEN
CONTROL GET CHECK CB.HNDL, CB.CTL TO lRes
IF lRes THEN
SetWindowPos CB.HNDL, %HWND_TOPMOST, 0, 0, 0, 0, %SWP_NOMOVE OR %SWP_NOSIZE
ELSE
SetWindowPos CB.HNDL, %HWND_NOTOPMOST, 0, 0, 0, 0, %SWP_NOMOVE OR %SWP_NOSIZE
END IF
END IF
CASE %IDC_LBL_START 'Start drag
IF CBCTLMSG = %STN_CLICKED THEN
hDC = GetDC(0) ' use entire desktop's dc
SetCapture CB.HNDL
StartDrag = 1
MOUSEPTR 2
GOSUB DrawZoom
END IF
CASE %IDCANCEL
IF CB.CTLMSG = %BN_CLICKED OR CB.CTLMSG = 1 THEN
DIALOG END CB.HNDL, 0
END IF
END SELECT
CASE %WM_MOUSEMOVE ' on mouse move, check every pixel's color under mouse cursor
IF StartDrag THEN
GOSUB DrawZoom
GetCursorPos pt
IF iCol <> GetPixel(hDC, pt.x, pt.y) THEN
iCol = GetPixel(hDC, pt.x, pt.y)
GOSUB DoColors
END IF
END IF
CASE %WM_LBUTTONUP
IF StartDrag = 0 THEN EXIT FUNCTION
GetCursorPos pt
iCol = GetPixel(hDC, pt.x, pt.y)
ReleaseDc(0, hDC)
ReleaseCapture
StartDrag = 0
MOUSEPTR 1
CASE %WM_NOTIFY
SELECT CASE CBWPARAM
CASE %IDC_TAB
SELECT CASE CB.NMCODE
CASE %TCN_SELCHANGE ' Tab page has changed
TAB GET SELECT CB.HNDL, %IDC_TAB TO lRes
onSelChange(lRes)
END SELECT
END SELECT
END SELECT
EXIT FUNCTION
'----------------------------------------------------------
DoColors:
r = GetRValue(iCol) : g = GetGValue(iCol) : b = GetBValue(iCol)
wStr = " RGB(" + FORMAT$(r) + ", " + _
FORMAT$(g) + ", " + _
FORMAT$(b) + ")" ' <- RGB colors here
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, wStr
wStr = "&H" + HEX$(b, 2) + HEX$(g, 2) + HEX$(r, 2) ' <- BGR colors here
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, wStr
LOCAL c AS LONG
lRes = 0
FOR c = 1 TO UBOUND(tPBcol)
IF wStr = tPBcol(c).wzCol THEN lRes = c : EXIT FOR
NEXT
IF lRes THEN
wStr = tPBcol(lRes).wzEqu
ELSE
FOR c = 1 TO UBOUND(tSysCol) ' could it be a system color?
IF wStr = tSysCol(c).wzCol THEN lRes = c : EXIT FOR
NEXT
IF lRes THEN
wStr = tSysCol(lRes).wzEqu
ELSE
wStr = ""
END IF
END IF
CONTROL SET TEXT CB.HNDL, %IDC_TEXTBOX1, wStr
CONTROL REDRAW CB.HNDL, %IDC_TEXTBOX1
CONTROL SET COLOR CB.HNDL, %IDC_LBL_SHOW, -1, iCol
CONTROL REDRAW CB.HNDL, %IDC_LBL_SHOW
RETURN
'----------------------------------------------------------
DrawZoom: ' draw a zoom viewport in label %IDC_LBL_ZOOM
LOCAL hDC2, hZoom, x, y AS LONG
hZoom = GetDlgItem(CB.HNDL, %IDC_LBL_ZOOM)
GetClientRect hZoom, rc
GetCursorPos pt
hDC2 = GetDC(hZoom)
StretchBlt hDC2, 0, 0, rc.nRight, rc.nBottom, _ ' zoom 3x3 around mouse
hDC, pt.x-1, pt.y-1, 3, 3, %SRCCOPY
x = rc.nRight
y = rc.nBottom
hPen = CreatePen(%PS_SOLID, 1, RGB(0,0,0)) ' draw black rect
hPen = SelectObject(hDC2, hPen)
hBrush = SelectObject(hDC2, GetStockObject(%HOLLOW_BRUSH))
Rectangle hDC2, x/3, y/3, x/3*2, y/3*2
DeleteObject SelectObject(hDC2, hPen)
hPen = CreatePen(%PS_SOLID, 1, RGB(255,255,255)) ' draw smaller white rect
hPen = SelectObject(hDC2, hPen)
Rectangle hDC2, x/3+1, y/3+1, x/3*2-1, y/3*2-1
hBrush = SelectObject(hDC2, hBrush)
DeleteObject SelectObject(hDC2, hPen)
ReleaseDc hZoom, hDC2
RETURN
END FUNCTION
'====================================================================
' Tab Control Page 1 Callback
'--------------------------------------------------------------------
CALLBACK FUNCTION TabProc1
SELECT CASE AS LONG CB.MSG
CASE %WM_DRAWITEM : FUNCTION = onDrawItem(1, CB.WPARAM, CB.LPARAM)
CASE %WM_COMMAND : IF CB.CTL = %IDC_LISTBOX1 AND _
CB.CTLMSG = %LBN_SELCHANGE THEN onSelChange(1)
END SELECT
END FUNCTION
'====================================================================
' Tab Control Page 2 Callback
'--------------------------------------------------------------------
CALLBACK FUNCTION TabProc2
SELECT CASE AS LONG CB.MSG
CASE %WM_DRAWITEM : FUNCTION = onDrawItem(2, CB.WPARAM, CB.LPARAM)
CASE %WM_COMMAND : IF CB.CTL = %IDC_LISTBOX1 AND _
CB.CTLMSG = %LBN_SELCHANGE THEN onSelChange(2)
END SELECT
END FUNCTION
'====================================================================
' Tab Control Page 3 Callback
'--------------------------------------------------------------------
CALLBACK FUNCTION TabProc3
SELECT CASE AS LONG CB.MSG
CASE %WM_DRAWITEM : FUNCTION = onDrawItem(3, CB.WPARAM, CB.LPARAM)
CASE %WM_COMMAND : IF CB.CTL = %IDC_LISTBOX1 AND _
CB.CTLMSG = %LBN_SELCHANGE THEN onSelChange(3)
END SELECT
END FUNCTION
'====================================================================
' Tab Control Page 4 Callback
'--------------------------------------------------------------------
CALLBACK FUNCTION TabProc4
LOCAL c, fcolorval, lRes AS LONG, wStr AS WSTRING
LOCAL r, g, b AS BYTE, iCol AS LONG
STATIC cc AS custcolors
SELECT CASE AS LONG CB.MSG
CASE %WM_INITDIALOG : gfColor = &H808080
CASE %WM_DRAWITEM : FUNCTION = onDrawItem(4, CB.WPARAM, CB.LPARAM)
CASE %WM_COMMAND
IF CB.CTL = %IDC_LISTBOX1 AND _
CB.CTLMSG = %LBN_SELCHANGE THEN
gfColor = onSelChange(4)
CONTROL SET COLOR hTab4, %IDC_LABEL4, -1, gfColor
CONTROL REDRAW hTab4, %IDC_LABEL4
ELSEIF CB.CTL = %IDC_BTN_COLOR AND _
CB.CTLMSG = %BN_CLICKED THEN
DISPLAY COLOR CBHNDL, 0, 0, gfColor, cc, %CC_FULLOPEN TO fcolorval&
IF fcolorval > -1 THEN ' special case - color may not be one
gfColor = fcolorval ' of 48 Basic colors, so we need to scan array
wStr = "&H" + HEX$(gfColor, 6) : lRes = 0
FOR c = 1 TO UBOUND(tBasCol) ' could it be a Base color?
IF wStr = tBasCol(c).wzCol THEN lRes = c : EXIT FOR
NEXT
IF lRes THEN ' if it was one of the listed 48 basic colors
iCol = VAL(tBasCol(c).wzCol)
LISTBOX SELECT CB.HNDL, %IDC_LISTBOX1, c
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, tBasCol(c).wzEqu
ELSE
LISTBOX UNSELECT CB.HNDL, %IDC_LISTBOX1
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, ""
iCol = fcolorval
END IF
r = GetRValue(iCol) : g = GetGValue(iCol) : b = GetBValue(iCol)
wStr = " RGB(" + FORMAT$(r) + ", " + _
FORMAT$(g) + ", " + _
FORMAT$(b) + ")"
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, wStr
wStr = "&H" + HEX$(iCol, 6)
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, wStr
CONTROL SET COLOR hTab4, %IDC_LABEL4, -1, gfColor
CONTROL REDRAW hTab4, %IDC_LABEL4
END IF
END IF
END SELECT
END FUNCTION
'====================================================================
' Tab Control ListBox handler
'--------------------------------------------------------------------
FUNCTION onSelChange(iPage AS LONG) AS LONG
LOCAL wStr AS WSTRING
LOCAL r, g, b AS BYTE, iCol AS LONG
SELECT CASE iPage
CASE 1
LISTBOX GET SELECT hTab1, %IDC_LISTBOX1 TO iCol
IF iCol = 0 THEN
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, ""
EXIT FUNCTION
END IF
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, tPbCol(iCol).wzEqu
iCol = VAL(tPbCol(iCol).wzCol)
CASE 2
LISTBOX GET SELECT hTab2, %IDC_LISTBOX1 TO iCol
IF iCol = 0 THEN
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, ""
EXIT FUNCTION
END IF
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, tSysCol(iCol).wzEqu
iCol = VAL(tSysCol(iCol).wzCol)
CASE 3
LISTBOX GET SELECT hTab3, %IDC_LISTBOX1 TO iCol
IF iCol = 0 THEN
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, ""
EXIT FUNCTION
END IF
wStr = tQbCol(iCol).wzEqu
REPLACE $TAB WITH SPACE$(5) IN wStr
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, wStr
iCol = VAL(tQbCol(iCol).wzCol)
CASE 4
LISTBOX GET SELECT hTab4, %IDC_LISTBOX1 TO iCol
IF iCol = 0 THEN
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, ""
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, ""
IF gfColor < 0 THEN EXIT FUNCTION ELSE iCol = gfColor : EXIT SELECT
END IF
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX1, tBasCol(iCol).wzEqu
iCol = VAL(tBasCol(iCol).wzCol)
END SELECT
r = GetRValue(iCol) : g = GetGValue(iCol) : b = GetBValue(iCol)
wStr = " RGB(" + FORMAT$(r) + ", " + _
FORMAT$(g) + ", " + _
FORMAT$(b) + ")"
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX2, wStr
wStr = "&H" + HEX$(iCol, 6)
CONTROL SET TEXT ghDlg, %IDC_TEXTBOX3, wStr
FUNCTION = iCol
END FUNCTION
'====================================================================
' Tab Control ListBoxes %WM_DRAWITEM handler
'--------------------------------------------------------------------
FUNCTION onDrawItem(iPage AS LONG, wParam AS LONG, lParam AS LONG) AS LONG
LOCAL iCol, iNum AS LONG
LOCAL hBrush, hPen AS DWORD, rc AS RECT
LOCAL lpdis AS DRAWITEMSTRUCT PTR, wsTxt, wsEqu AS WSTRING
lpdis = lParam
IF @lpdis.itemID = &HFFFFFFFF& THEN EXIT FUNCTION
rc = @lpdis.rcItem
SELECT CASE @lpdis.itemAction
CASE %ODA_DRAWENTIRE, %ODA_SELECT
'DRAW BACKGROUND
IF (@lpdis.itemState AND %ODS_SELECTED) = 0 THEN 'Not selected
SetBkColor @lpdis.hDC, GetSysColor(%COLOR_INFOBK) 'Set text Background
SetTextColor @lpdis.hDC, GetSysColor(%COLOR_WINDOWTEXT) 'Set text color GetSysColor(%COLOR_INFOBK)
FillRect @lpdis.hDC, @lpdis.rcItem, GetSysColorBrush(%COLOR_INFOBK)
ELSE 'IF iPage < 4 THEN
SetBkColor @lpdis.hDC, GetSysColor(%COLOR_WINDOWTEXT) 'Set text Background
SetTextColor @lpdis.hDC, GetSysColor(%COLOR_WINDOW) 'Set text color
IF iPage < 4 THEN @lpdis.rcItem.nLeft = 66 'adjust rect - only use highlight colors in text-part
FillRect @lpdis.hDC, @lpdis.rcItem, GetSysColorBrush(%COLOR_WINDOWTEXT)
END IF
'PREPARE
iNum = @lpdis.itemID+1
SELECT CASE AS LONG iPage
CASE 1
wsTxt = tPBcol(iNum).wzEqu
iCol = VAL(tPBcol(iNum).wzCol)
CASE 2
wsTxt = tSysCol(iNum).wzEqu
iCol = VAL(tSysCol(iNum).wzCol)
CASE 3
wsTxt = PARSE$(tQbcol(iNum).wzEqu, $TAB, 1)
wsEqu = PARSE$(tQbcol(iNum).wzEqu, $TAB, 2)
iCol = VAL(tQbcol(iNum).wzCol)
CASE 4
wsTxt = "" 'tBascol(iNum).wzEqu
iCol = VAL(tBascol(iNum).wzCol)
END SELECT
'DRAW TEXT
IF LEN(wsTxt) THEN
@lpdis.rcItem.nLeft = 68 'adjust left side of rect for DrawText call
DrawText @lpdis.hDC, BYCOPY wsTxt, LEN(wsTxt), _
@lpdis.rcItem, %DT_SINGLELINE OR %DT_LEFT OR %DT_VCENTER
END IF
IF LEN(wsEqu) THEN
@lpdis.rcItem.nLeft = @lpdis.rcItem.nRight/2 + 20 'adjust left side of rect for DrawText call
DrawText @lpdis.hDC, BYCOPY wsEqu, LEN(wsEqu), _
@lpdis.rcItem, %DT_SINGLELINE OR %DT_LEFT OR %DT_VCENTER
END IF
'PAINT COLOR RECTANGLE (using RoundRect for nicer look)
@lpdis.rcItem = rc
IF iPage < 4 THEN
rc.nLeft = 3 : rc.nRight = 64 'Set cordinates
rc.ntop = @lpdis.rcItem.ntop + 2
rc.nbottom = @lpdis.rcItem.nbottom - 3
ELSE
rc.nLeft = @lpdis.rcItem.nLeft + 2
rc.nRight = @lpdis.rcItem.nRight - 2 'Set cordinates
rc.ntop = @lpdis.rcItem.ntop + 2
rc.nbottom = @lpdis.rcItem.nbottom - 3
END IF
hBrush = CreateSolidBrush(iCol) 'Create a brush with proper color
hBrush = SelectObject(@lpdis.hDC, hBrush) 'Select brush into LB's device context
RoundRect @lpdis.hDC, rc.nLeft, rc.ntop, rc.nRight, rc.nbottom, 3, 3 'Draw color
DeleteObject SelectObject(@lpdis.hDC, hBrush) 'Select original brush back and delete created
'DRAW GRID LINES
hPen = CreatePen(%PS_SOLID, 1, GetSysColor(%COLOR_3DSHADOW))
hPen = SelectObject(@lpdis.hDC, hPen)
MoveToEx @lpdis.hDC, 0, @lpdis.rcItem.nBottom - 1, BYVAL %NULL
LineTo @lpdis.hDC, @lpdis.rcItem.nRight, @lpdis.rcItem.nBottom - 1
DeleteObject SelectObject(@lpdis.hDC, hPen)
FUNCTION = %TRUE : EXIT FUNCTION 'return %TRUE and exit
CASE %ODA_FOCUS
@lpdis.rcItem.nbottom = @lpdis.rcItem.nbottom - 1
DrawFocusRect @lpdis.hDC, @lpdis.rcItem 'draw focus rectangle if in focus
FUNCTION = %TRUE : EXIT FUNCTION 'return %TRUE and exit
END SELECT
END FUNCTION
'======================================================================
' Fill tBasCol array
'----------------------------------------------------------------------
SUB SetBasColorArray()
LOCAL c AS LONG
REDIM tBasCol(1 TO 48) AS cData
INCR c : tBasCol(c).wzCol = "&H8080FF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H0000FF" : tBasCol(c).wzEqu = "%RGB_RED"
INCR c : tBasCol(c).wzCol = "&H404080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H000080" : tBasCol(c).wzEqu = "%RGB_MAROON"
INCR c : tBasCol(c).wzCol = "&H000040" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H000000" : tBasCol(c).wzEqu = "%RGB_BLACK"
INCR c : tBasCol(c).wzCol = "&H80FFFF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H00FFFF" : tBasCol(c).wzEqu = "%RGB_YELLOW"
INCR c : tBasCol(c).wzCol = "&H4080FF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H0080FF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H004080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H008080" : tBasCol(c).wzEqu = "%RGB_OLIVE"
INCR c : tBasCol(c).wzCol = "&H80FF80" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H00FF80" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H00FF00" : tBasCol(c).wzEqu = "%RGB_LIME"
INCR c : tBasCol(c).wzCol = "&H008000" : tBasCol(c).wzEqu = "%RGB_GREEN"
INCR c : tBasCol(c).wzCol = "&H004000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H408080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H80FF00" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H40FF00" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H808000" : tBasCol(c).wzEqu = "%RGB_TEAL"
INCR c : tBasCol(c).wzCol = "&H408000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H404000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H808080" : tBasCol(c).wzEqu = "%RGB_GRAY"
INCR c : tBasCol(c).wzCol = "&HFFFF80" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFFFF00" : tBasCol(c).wzEqu = "%RGB_CYAN"
INCR c : tBasCol(c).wzCol = "&H804000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFF0000" : tBasCol(c).wzEqu = "%RGB_BLUE"
INCR c : tBasCol(c).wzCol = "&H800000" : tBasCol(c).wzEqu = "%RGB_NAVY"
INCR c : tBasCol(c).wzCol = "&H808040" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFF8000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HC08000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFF8080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HA00000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H400000" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HC0C0C0" : tBasCol(c).wzEqu = "%RGB_SILVER"
INCR c : tBasCol(c).wzCol = "&HC080FF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HC08080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H400080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H800080" : tBasCol(c).wzEqu = "%RGB_PURPLE"
INCR c : tBasCol(c).wzCol = "&H400040" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H400040" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFF80FF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFF00FF" : tBasCol(c).wzEqu = "%RGB_MAGENTA"
INCR c : tBasCol(c).wzCol = "&H8000FF" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFF0080" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&H800040" : tBasCol(c).wzEqu = ""
INCR c : tBasCol(c).wzCol = "&HFFFFFF" : tBasCol(c).wzEqu = "%RGB_WHITE"
END SUB
'======================================================================
' Fill tQBcol array
'----------------------------------------------------------------------
SUB SetQbColorArray()
LOCAL c AS LONG
REDIM tQBcol(1 TO 16) AS cData
INCR c : tQBcol(c).wzEqu = "Black" + $TAB + "%RGB_BLACK" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,0,0), 6)
INCR c : tQBcol(c).wzEqu = "Blue" + $TAB + "%RGB_NAVY" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,0,128), 6)
INCR c : tQBcol(c).wzEqu = "Green" + $TAB + "%RGB_GREEN" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,128,0), 6)
INCR c : tQBcol(c).wzEqu = "Cyan" + $TAB + "%RGB_TEAL" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,128,128), 6)
INCR c : tQBcol(c).wzEqu = "Red" + $TAB + "%RGB_MAROON" : tQBcol(c).wzCol = "&H" + HEX$(RGB(128,0,0), 6)
INCR c : tQBcol(c).wzEqu = "Magenta" + $TAB + "%RGB_PURPLE" : tQBcol(c).wzCol = "&H" + HEX$(RGB(128,0,128), 6)
INCR c : tQBcol(c).wzEqu = "Yellow/Brown" + $TAB + "%RGB_OLIVE" : tQBcol(c).wzCol = "&H" + HEX$(RGB(128,128,0), 6)
INCR c : tQBcol(c).wzEqu = "Light Gray" + $TAB + "%RGB_SILVER" : tQBcol(c).wzCol = "&H" + HEX$(RGB(192,192,192), 6)
INCR c : tQBcol(c).wzEqu = "Gray" + $TAB + "%RGB_GRAY" : tQBcol(c).wzCol = "&H" + HEX$(RGB(128,128,128), 6)
INCR c : tQBcol(c).wzEqu = "Light Blue" + $TAB + "%RGB_BLUE" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,0, 255), 6)
INCR c : tQBcol(c).wzEqu = "Light Green" + $TAB + "%RGB_LIME" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,255,0), 6)
INCR c : tQBcol(c).wzEqu = "Light Cyan" + $TAB + "%RGB_CYAN" : tQBcol(c).wzCol = "&H" + HEX$(RGB(0,255,255), 6)
INCR c : tQBcol(c).wzEqu = "Light Red" + $TAB + "%RGB_RED" : tQBcol(c).wzCol = "&H" + HEX$(RGB(255,0,0), 6)
INCR c : tQBcol(c).wzEqu = "Light Magenta" + $TAB + "%RGB_MAGENTA" : tQBcol(c).wzCol = "&H" + HEX$(RGB(255,0,255), 6)
INCR c : tQBcol(c).wzEqu = "Light Yellow" + $TAB + "%RGB_YELLOW" : tQBcol(c).wzCol = "&H" + HEX$(RGB(255,255,0), 6)
INCR c : tQBcol(c).wzEqu = "Bright White" + $TAB + "%RGB_WHITE" : tQBcol(c).wzCol = "&H" + HEX$(RGB(255,255,255), 6)
END SUB
'======================================================================
' Fill tSysCol array
'----------------------------------------------------------------------
SUB SetSysColorArray()
LOCAL c AS LONG
REDIM tSysCol(1 TO 30) AS cData
INCR c : tSysCol(c).wzEqu = "%COLOR_SCROLLBAR" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_SCROLLBAR), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_DESKTOP" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_DESKTOP), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_ACTIVECAPTION" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_ACTIVECAPTION), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_GRADIENTACTIVECAPTION" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_GRADIENTACTIVECAPTION), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_INACTIVECAPTION" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_INACTIVECAPTION), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_GRADIENTINACTIVECAPTION" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_GRADIENTINACTIVECAPTION), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_INACTIVECAPTIONTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_INACTIVECAPTIONTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_WINDOW" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_WINDOW), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_WINDOWTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_WINDOWTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_WINDOWFRAME" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_WINDOWFRAME), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_MENUTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_MENUTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_CAPTIONTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_CAPTIONTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_ACTIVEBORDER" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_ACTIVEBORDER), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_INACTIVEBORDER" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_INACTIVEBORDER), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_APPWORKSPACE" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_APPWORKSPACE), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_HIGHLIGHTTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_HIGHLIGHTTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_3DFACE" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_3DFACE), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_3DSHADOW" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_3DSHADOW), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_3DDKSHADOW" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_3DDKSHADOW), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_BTNTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_BTNTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_GRAYTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_GRAYTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_3DLIGHT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_3DLIGHT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_INFOTEXT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_INFOTEXT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_INFOBK" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_INFOBK), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_3DHIGHLIGHT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_3DHIGHLIGHT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_MENU" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_MENU), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_MENUBAR" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_MENUBAR), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_MENUHILIGHT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_MENUHILIGHT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_HIGHLIGHT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_HIGHLIGHT), 6)
INCR c : tSysCol(c).wzEqu = "%COLOR_HOTLIGHT" : tSysCol(c).wzCol = "&H" + HEX$(GetSysColor(%COLOR_HOTLIGHT), 6)
END SUB
'======================================================================
' Fill tPBcol array
'----------------------------------------------------------------------
SUB SetPbColorArray()
LOCAL c, d, e AS LONG
e = (DATACOUNT-1)/2
REDIM tPBcol(1 TO e) AS cData
d = 1
FOR c = 1 TO e
tPBcol(c).wzCol = READ$(d) : INCR d
tPBcol(c).wzEqu = READ$(d) : INCR d
NEXT
'Red Colors
DATA &H5C5CCD, %RGB_INDIANRED, &H8080F0, %RGB_LIGHTCORAL, &H7280FA, %RGB_SALMON
DATA &H7A96E9, %RGB_DARKSALMON, &H7AA0FF, %RGB_LIGHTSALMON, &H3C14DC, %RGB_CRIMSON
DATA &H0000FF, %RGB_RED, &H2222B2, %RGB_FIREBRICK, &H00008B, %RGB_DARKRED
'Pink Colors
DATA &HCBC0FF, %RGB_PINK, &HC1B6FF, %RGB_LIGHTPINK, &HB469FF, %RGB_HOTPINK
DATA &H9314FF, %RGB_DEEPPINK, &H8515C7, %RGB_MEDIUMVIOLETRED, &H9370DB, %RGB_PALEVIOLETRED
'Orange Colors
DATA &H7AA0FF, %RGB_LIGHTSALMON, &H507FFF, %RGB_CORAL, &H4763FF, %RGB_TOMATO
DATA &H0045FF, %RGB_ORANGERED, &H008CFF, %RGB_DARKORANGE, &H00A5FF, %RGB_ORANGE
'Yellow Colors
DATA &H00D7FF, %RGB_GOLD, &H00FFFF, %RGB_YELLOW, &HE0FFFF, %RGB_LIGHTYELLOW
DATA &HCDFAFF, %RGB_LEMONCHIFFON, &HD2FAFA, %RGB_LIGHTGOLDENRODYELLOW, &HD5EFFF, %RGB_PAPAYAWHIP
DATA &HB5E4FF, %RGB_MOCCASIN, &HB9DAFF, %RGB_PEACHPUFF, &HAAE8EE, %RGB_PALEGOLDENROD
DATA &H8CE6F0, %RGB_KHAKI, &H6BB7BD, %RGB_DARKKHAKI
'Purple Colors
DATA &HFAE6E6, %RGB_LAVENDER, &HD8BFD8, %RGB_THISTLE, &HDDA0DD, %RGB_PLUM
DATA &HEE82EE, %RGB_VIOLET, &HD670DA, %RGB_ORCHID, &HFF00FF, %RGB_MAGENTA
DATA &HD355BA, %RGB_MEDIUMORCHID, &HDB7093, %RGB_MEDIUMPURPLE, &HE22B8A, %RGB_BLUEVIOLET
DATA &HD30094, %RGB_DARKVIOLET, &HCC3299, %RGB_DARKORCHID, &H8B008B, %RGB_DARKMAGENTA
DATA &H800080, %RGB_PURPLE, &H82004B, %RGB_INDIGO, &HCD5A6A, %RGB_SLATEBLUE
DATA &H8B3D48, %RGB_DARKSLATEBLUE, &HEE687B, %RGB_MEDIUMSLATEBLUE
'Green Colors
DATA &H2FFFAD, %RGB_GREENYELLOW, &H00FF7F, %RGB_CHARTREUSE, &H00FC7C, %RGB_LAWNGREEN
DATA &H00FF00, %RGB_LIME, &H32CD32, %RGB_LIMEGREEN, &H98FB98, %RGB_PALEGREEN
DATA &H90EE90, %RGB_LIGHTGREEN, &H9AFA00, %RGB_MEDIUMSPRINGGREEN, &H7FFF00, %RGB_SPRINGGREEN
DATA &H71B33C, %RGB_MEDIUMSEAGREEN, &H578B2E, %RGB_SEAGREEN, &H228B22, %RGB_FORESTGREEN
DATA &H008000, %RGB_GREEN, &H006400, %RGB_DARKGREEN, &H32CD9A, %RGB_YELLOWGREEN
DATA &H238E6B, %RGB_OLIVEDRAB, &H008080, %RGB_OLIVE, &H2F6B55, %RGB_DARKOLIVEGREEN
DATA &HAACD66, %RGB_MEDIUMAQUAMARINE, &H8FBC8F, %RGB_DARKSEAGREEN, &HAAB220, %RGB_LIGHTSEAGREEN
DATA &H8B8B00, %RGB_DARKCYAN, &H808000, %RGB_TEAL
'Blue Colors
DATA &HFFFF00, %RGB_CYAN, &HFFFFE0, %RGB_LIGHTCYAN, &HEEEEAF, %RGB_PALETURQUOISE
DATA &HD4FF7F, %RGB_AQUAMARINE, &HD0E040, %RGB_TURQUOISE, &HCCD148, %RGB_MEDIUMTURQUOISE
DATA &HD1CE00, %RGB_DARKTURQUOISE, &HA09E5F, %RGB_CADETBLUE, &HB48246, %RGB_STEELBLUE
DATA &HDEC4B0, %RGB_LIGHTSTEELBLUE, &HE6E0B0, %RGB_POWDERBLUE, &HE6D8AD, %RGB_LIGHTBLUE
DATA &HEBCE87, %RGB_SKYBLUE, &HFACE87, %RGB_LIGHTSKYBLUE, &HFFBF00, %RGB_DEEPSKYBLUE
DATA &HFF901E, %RGB_DODGERBLUE, &HED9564, %RGB_CORNFLOWERBLUE, &HEE687B, %RGB_MEDIUMSLATEBLUE
DATA &HE16941, %RGB_ROYALBLUE, &HFF0000, %RGB_BLUE, &HCD0000, %RGB_MEDIUMBLUE
DATA &H8B0000, %RGB_DARKBLUE, &H800000, %RGB_NAVY, &H701919, %RGB_MIDNIGHTBLUE
'Brown Colors
DATA &HDCF8FF, %RGB_CORNSILK, &HCDEBFF, %RGB_BLANCHEDALMOND, &HC4E4FF, %RGB_BISQUE
DATA &HADDEFF, %RGB_NAVAJOWHITE, &HB3DEF5, %RGB_WHEAT, &H87B8DE, %RGB_BURLYWOOD
DATA &H8CB4D2, %RGB_TAN, &H8F8FBC, %RGB_ROSYBROWN, &H60A4F4, %RGB_SANDYBROWN
DATA &H20A5DA, %RGB_GOLDENROD, &H0B86B8, %RGB_DARKGOLDENROD, &H3F85CD, %RGB_PERU
DATA &H1E69D2, %RGB_CHOCOLATE, &H13458B, %RGB_SADDLEBROWN, &H2D52A0, %RGB_SIENNA
DATA &H2A2AA5, %RGB_BROWN, &H000080, %RGB_MAROON
'White Colors
DATA &HFFFFFF, %RGB_WHITE, &HFAFAFF, %RGB_SNOW, &HF0FFF0, %RGB_HONEYDEW
DATA &HFAFFF5, %RGB_MINTCREAM, &HFFFFF0, %RGB_AZURE, &HFFF8F0, %RGB_ALICEBLUE
DATA &HFFF8F8, %RGB_GHOSTWHITE, &HF5F5F5, %RGB_WHITESMOKE, &HEEF5FF, %RGB_SEASHELL
DATA &HDCF5F5, %RGB_BEIGE, &HE6F5FD, %RGB_OLDLACE, &HF0FAFF, %RGB_FLORALWHITE
DATA &HF0FFFF, %RGB_IVORY, &HD7EBFA, %RGB_ANTIQUEWHITE, &HE6F0FA, %RGB_LINEN
DATA &HF5F0FF, %RGB_LAVENDERBLUSH, &HE1E4FF, %RGB_MISTYROSE
'Gray Colors
DATA &HDCDCDC, %RGB_GAINSBORO, &HD3D3D3, %RGB_LIGHTGRAY, &HC0C0C0, %RGB_SILVER
DATA &HA9A9A9, %RGB_DARKGRAY, &H808080, %RGB_GRAY, &H696969, %RGB_DIMGRAY
DATA &H998877, %RGB_LIGHTSLATEGRAY, &H908070, %RGB_SLATEGRAY, &H4F4F2F, %RGB_DARKSLATEGRAY
DATA &H000000, %RGB_BLACK
END SUB