Welcome, Guest
You have to register before you can post on our site.

Username
  

Password
  





Search Forums

(Advanced Search)

Forum Statistics
» Members: 136
» Latest member: Rob Wooding
» Forum threads: 146
» Forum posts: 1,132

Full Statistics

Latest Threads
WorldWeather.bas
Forum: Source Code Library
Last Post: Stanley Durham
1 hour ago
» Replies: 1
» Views: 13
RSA2048 encryption
Forum: Programming
Last Post: Mannish Bhandari
9 hours ago
» Replies: 4
» Views: 102
logout
Forum: Suggestions and discussion about PUMP
Last Post: Albert Richheimer
Yesterday, 10:21
» Replies: 1
» Views: 61
WinTick 1.1
Forum: Source Code Library
Last Post: Borje Hagsten
Yesterday, 00:33
» Replies: 0
» Views: 50
RSA-2048 in PowerBasic (n...
Forum: Source Code Library
Last Post: Steven Pringels
12.11.2026, 20:28
» Replies: 0
» Views: 59
Insert image in post
Forum: Suggestions and discussion about PUMP
Last Post: Dale Yarker
05.11.2026, 14:47
» Replies: 3
» Views: 258
GDI+ Gauges custom contro...
Forum: Programming
Last Post: Jules Marchildon
04.11.2026, 13:12
» Replies: 7
» Views: 762
Next Gen Visual Designer ...
Forum: Programming
Last Post: Jules Marchildon
27.10.2026, 04:38
» Replies: 14
» Views: 1,782
Program that won't close
Forum: PowerBASIC for Windows
Last Post: Mike Doty
26.10.2026, 15:54
» Replies: 6
» Views: 576
EnableVisualStyles.bas
Forum: Source Code Library
Last Post: Stanley Durham
25.10.2026, 01:12
» Replies: 5
» Views: 534

 
  How many "1" bits /Is Number a Power of 2
Posted by: Dale Yarker - 16.03.2026, 11:54 - Forum: Source Code Library - No Replies

Code:
'The FASTPROCs here are for both PBWin 10 and PBCC 6.
'For older PB versions change FASTPROC to FUNCTION.
'The demo (in PBMAIN below) would need significant change to compile in older
'versions of PB.
#compile exe
#dim all
#if %def(%pb_cc32) 'ignore this in PBWin
  #console off     'no unneeded in PBCC
#endif
'
'#### Please start thread in Programming for comments/questions. ####
'
'I want a solitare game that was not in old PB formum Source Code.
'Do it myself.
'That requires shuffling cards. Instead of repeating shuffle code for other
'games make a DLL.
'Shuffling requires PRNG(s), and seeds for PRNDs. They are useful for more
'than just card game, so another DLL.
'One of the PRNG algorithms fails if seed is a power of 2.
'
'(PRNG is pseudo Random Number Generator, NUT is Number Under Test.)
'
'How many bits are "1"?
''Simple use of the assembly POPCNT needed in power of 2 procs.
''is DWORD/LONG agnostic
fastproc BitCount(byval NUT as long) as long
  ! popcnt eax, NUT
  ! mov NUT, eax
end fastproc = NUT
'
'Is a DWORD number a power of 2?
fastproc IsPowerOf2Dw (byval NUT as long) as long
  ! mov ebx, NUT        'so not to modify NUT
  ! and ebx, &h00000001 'without this 1 returns as PO2
  !  jz IsEven
  ! jmp NotPO2
  IsEven:
  ! popcnt ebx, NUT
  ! cmp ebx, 1
  ! jne NotPO2
  ! mov NUT, -1
  ! jmp Done
  NotPO2:          '   -4 -8
  ! mov NUT, 0
  Done:
end fastproc = NUT
'
'Is a LONG number a power of 2?
''(Second procedure because in DWORD bit 31 is MSB of the number, while
'''in a LONG it is the sign flag and remaining bits are in 2s compliment
'''format.)
fastproc IsPowerOf2Lg (byval NUT as long) as long
  'check if NUT is negative
  !  bt NUT, 31
  ! jc NotPO2
  ! mov ebx, NUT
  ! and ebx, &00000001
  !  jz IsEven
  ! jmp NotPO2
  IsEven:
  ! popcnt ebx, NUT
  ! cmp ebx, 1
  ! jne NotPO2
  ! mov NUT, -1
  ! jmp Done
  NotPO2:
  ! mov NUT, 0
  Done:
end fastproc = NUT
'
'###############################################################################
function pbmain () as long
  local hTWin, NumD as dword
  local NumL, Retrn as long
  txt.window("BitCount, IsPowerOf2Dw and IsPowerOf2Lg"$$, 75, 50, 27, 40) _
                                                                        to hTWin
  '
  txt.color = %rgb_blue : txt.print "BitCount" : txt.color = %rgb_black
  NumL = 1 : Retrn = BitCount(NumL) : gosub PrintCount
  NumL = 2 : Retrn = BitCount(NumL) : gosub PrintCount
  NumL = 15 : Retrn = BitCount(NumL) : gosub PrintCount
  NumL = &h80050006 : Retrn = BitCount(NumL) : gosub PrintCount
  '
  txt.print : txt.color = %rgb_blue
  txt.print "Is DWORD a power of 2?"$$ : txt.color = %rgb_black
  NumD = 1 : Retrn = IsPowerOf2Dw(NumD) : gosub PrintDwd
  NumD = 4 : Retrn = IsPowerOf2Dw(NumD) : gosub PrintDwd
  NumD = 5 : Retrn = IsPowerOf2Dw(NumD) : gosub PrintDwd
  NumD = 4294967294 : Retrn = IsPowerOf2Dw(NumD) : gosub PrintDwd
  '
  txt.print  : txt.color = %rgb_blue
  txt.print "Is LONG a power of 2?"$$ : txt.color = %rgb_black
  NumL = 1 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = -1 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = 8 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = -8 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = 128 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = -128 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = 1024 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = -1024 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = 1026 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  NumL = -11026 : Retrn = IsPowerOf2Lg(NumL) : gosub PrintLng
  '
  txt.print
  txt.color = %rgb_green
  txt.print "Any key to close."$$
  txt.waitkey$
  exit function
  PrintCount:
    txt.print dec$(NumL) + " has " + dec$(Retrn) + " ""1"" bits."
  return
  PrintDwd:
    txt.print dec$(NumD);
    if Retrn then
      txt.print " is"$$
    else
      txt.print " is not"$$
    end if
  return
  PrintLng:
    txt.print dec$(NumL);
    if Retrn then
      txt.print " is"$$
    else
      txt.print " is not"$$
    end if
  return
end function
'#### Please start thread in Programming for comments/questions. ####

Print this item

  Add "Board Statistics"
Posted by: Eros Olmi - 28.01.2026, 19:28 - Forum: Suggestions and discussion about PUMP - Replies (3)

If possible, it would be nice to have "Board Statistics" box in the bottom of the forum like in official MyBB forum

Print this item

  PB Hex Viewer
Posted by: Eros Olmi - 27.01.2026, 23:07 - Forum: Source Code Library - Replies (7)

Ciao,

I've attached a project I was working some time ago where I experimented AI (OpenAI ChatGPT and Google Gemini together) to code with some help ... well ... a lot of help.

It's a classic visual HEX viewer control able to show some memory buffer.
Clicking on the left hidden panel there are some options to change viewer

Attached 100% 10.4 PowerBasic source code and executable.
Do whatever with the sources.

Hope it can help someone.

Ciao
Eros



Attached Files Thumbnail(s)
       

.bas   HexControl_v0.4.1.bas (Size: 102 KB / Downloads: 21)
.zip   HexControl_v0.4.1.EXE.zip (Size: 28.48 KB / Downloads: 8)
Print this item

  Making text unreadable, 1 sample code works, 2 do not work
Posted by: Robert Alvarez - 22.01.2026, 19:32 - Forum: PowerBASIC for Windows - Replies (8)

Found three code samples in the internet to make text unreadable.
First one can read text and encrypt it and decrypt .
The second and third seems to encrypt it but decrypt does not work.

First sample code:

Code:
#COMPILE EXE
#INCLUDE "WIN32API.INC"
GLOBAL hDlg AS LONG

CALLBACK FUNCTION ENDPROG()
DIALOG END CBHNDL, 1
END FUNCTION

FUNCTION PBMAIN () AS LONG
$REGISTER NONE
LOCAL result, i AS LONG

'1. Basic Character Shift (Caesar Cipher Style)
OPEN "secret 1a.dat" FOR OUTPUT AS #1
text$ = "This is my secret message."
FOR i = 1 TO LEN(text$)
PRINT #1, CHR$(ASC(MID$(text$, i, 1)) + 5);
NEXT
CLOSE #1

OPEN "secret 1a.dat" FOR INPUT AS #1: LINE INPUT #1, text$
? text$ 'encryt
FOR i = 1 TO LEN(text$)
text1$=text1$+CHR$(ASC(MID$(text$, i, 1)) - 5)
NEXT
? text1$  'decreypt

DIALOG NEW 0, "TEST 1", ,, 200, 150, %WS_MINIMIZEBOX+%WS_SYSMENU, 0 TO hDlg
CONTROL ADD LABEL, hDlg, 100, "LABEL 1",80, 40, 60, 14,
CONTROL ADD BUTTON,hDlg, 202, "&Exit Program",100, 100,55, 14, CALL ENDPROG
CONTROL SET FOCUS  hDlg, 202
DIALOG SHOW MODAL  hDlg TO result
END FUNCTION

Second sample code:

Code:
#COMPILE EXE
#INCLUDE "WIN32API.INC"
GLOBAL hDlg AS LONG

CALLBACK FUNCTION ENDPROG()
DIALOG END CBHNDL, 1
END FUNCTION

FUNCTION PBMAIN () AS LONG
$REGISTER NONE
LOCAL result, i, key AS LONG

'2. XOR Encoding
OPEN "secret2a.dat" FOR OUTPUT AS #1
text$ = "This is my secret message."
key = 123  ' Simple numeric key

FOR i = 1 TO LEN(text$)
    PRINT #1, CHR$(ASC(MID$(text$, i, 1)) XOR key);
NEXT
CLOSE #1
'XOR is reversible — use the same key to decode.


OPEN "secret2a.dat" FOR INPUT AS #1
GET #1,1, ch$: ? ch$$
decoded$ = ""
key = 123
WHILE NOT EOF(1)
    INPUT #1, ch$  ' : ? ch$
    decoded$ = decoded$ + CHR$(ASC(ch$) XOR key)  ': ? decoded$
WEND
CLOSE #1
? decoded$

DIALOG NEW 0, "TEST 1", ,, 200, 150, %WS_MINIMIZEBOX+%WS_SYSMENU, 0 TO hDlg
CONTROL ADD LABEL, hDlg, 100, "LABEL 1",80, 40, 60, 14,
CONTROL ADD BUTTON,hDlg, 202, "&Exit Program",100, 100,55, 14, CALL ENDPROG
CONTROL SET FOCUS  hDlg, 202
DIALOG SHOW MODAL  hDlg TO result
END FUNCTION

Third sample code:
Code:
#COMPILE EXE
#INCLUDE "WIN32API.INC"
GLOBAL hDlg AS LONG

CALLBACK FUNCTION ENDPROG()
DIALOG END CBHNDL, 1
END FUNCTION

FUNCTION PBMAIN () AS LONG
$REGISTER NONE
LOCAL result, i, mask AS LONG

'3. Binary Write with Random Mask
RANDOMIZE TIMER
OPEN "secret 3.dat" FOR BINARY AS #1
text$ = "This is my secret message."
FOR i = 1 TO LEN(text$)
    mask = RND(255)
    PUT$ #1, CHR$(ASC(MID$(text$, i, 1)) XOR mask)
NEXT
CLOSE #1


OPEN "secret 3.dat" FOR BINARY AS #1
decoded$ = ""
DO UNTIL EOF(1)
    GET$ #1, 1, mask1$
    GET$ #1, 1, data1$
    decoded$ = decoded$ + CHR$(ASC(data1$) XOR ASC(mask1$))
LOOP
CLOSE #1
? decoded$

DIALOG NEW 0, "TEST 1", ,, 200, 150, %WS_MINIMIZEBOX+%WS_SYSMENU, 0 TO hDlg
CONTROL ADD LABEL, hDlg, 100, "LABEL 1",80, 40, 60, 14,
CONTROL ADD BUTTON,hDlg, 202, "&Exit Program",100, 100,55, 14, CALL ENDPROG
CONTROL SET FOCUS  hDlg, 202
DIALOG SHOW MODAL  hDlg TO result
END FUNCTION
 
How to fix?

Print this item

  Using #RESOURCE RCDATA to implement the missing #RESOURCE AVI
Posted by: George Bleck - 14.01.2026, 17:14 - Forum: Source Code Library - No Replies

I posted this on the new community run PB Users Forum: https://pbusers.org/forum/viewtopic.php?t=239
Sharing here as well as I think it is useful for those that might not have joined there yet.

============================


It always bothered me that PowerBASIC never implemented a #RESOURCE AVI metastatement. If you want to include an AVI for the animation control via #RESOURCE metastatements it's impossible as you cannot animate directly from RCDATA (or other resource sections available via the #RESOURCE metastatement). It can only be done from an AVI resource section (or from a supplied file path). Yes, you can compile the AVI into an AVI resource section using an RC file compiler and add it as a PBR (which still works but was technically deprecated) or RES, but "you cannot add any other #RESOURCE metastatements in your program" as per the PowerBASIC documentation.

What this code does is allow you to embed AVIs into your code using #RESOURCE RCDATA. After you compile your code to DLL or EXE you run this patcher by supplying the DLL/EXE file path on the command line (or via drag-and-drop). It proceeds to enumerate the AVIs and moves them to an AVI resource section using UpdateResource.

Be aware that you will need to repatch the DLL/EXE each time you re-compile your code.
As such, this could be included in a tool chain to always run after a compile.

Processing is written to a log (AVIRscPtch_Log.csv) in the directory the targeted module is located. To facilitate running in a toolchain it runs silently if no errors occur, but uses MESSAGEBOX to report any errors (in addition to the log).

Code:
' Compiles under PBWIN or PBCC without changes
#COMPILE EXE "AVIRscPtch.exe"
#DIM ALL

'----------------------------------------------------------------------------(')

%UNICODE = 1

'----------------------------------------------------------------------------(')

$DDQ = $DQ + $DQ

'----------------------------------------------------------------------------(')

#INCLUDE "Win32API.inc" ' Roca Headers III_107

'----------------------------------------------------------------------------(')

GLOBAL v_ghMod AS DWORD
GLOBAL v_ghUpd AS DWORD
GLOBAL v_gsExe AS STRING

'----------------------------------------------------------------------------(')

FUNCTION fn_sCSV(BYVAL v_sText AS WSTRING) AS STRING
  IF INSTR(v_sText, ANY CHR$(34, 44)) THEN
      REPLACE $DQ WITH $DDQ IN v_sText
      FUNCTION = $DQ + v_sText + $DQ
  ELSE
      FUNCTION = v_sText
  END IF
END FUNCTION

'----------------------------------------------------------------------------(')

FUNCTION fn_sTimestamp() AS WSTRING
  LOCAL v_uST AS SYSTEMTIME
  GETSYSTEMTIME v_uST
  FUNCTION = _
      FORMAT$(v_uST.wYear, "0000") + "-" + _
      FORMAT$(v_uST.wMonth, "00") + "-" + _
      FORMAT$(v_uST.wDay, "00") + " " + _
      FORMAT$(v_uST.wHour, "00") + ":" + _
      FORMAT$(v_uST.wMinute, "00") + ":" + _
      FORMAT$(v_uST.wSecond, "00") + "Z"
END FUNCTION

'----------------------------------------------------------------------------(')

FUNCTION fn_sGetErrorText(BYVAL v_lError AS LONG) AS WSTRING
  LOCAL v_lReturn AS LONG
  LOCAL v_szBuffer AS WSTRINGZ * 256
  IF v_lError = %ERROR_SUCCESS THEN EXIT FUNCTION
  v_lReturn = FORMATMESSAGE(%FORMAT_MESSAGE_FROM_SYSTEM, BYVAL 0&, v_lError, BYVAL 0&, v_szBuffer, SIZEOF(v_szBuffer), BYVAL 0&)
  IF v_lReturn > 0 THEN FUNCTION = RTRIM$(LEFT$(v_szBuffer, v_lReturn), ANY $CRLF)
END FUNCTION

'----------------------------------------------------------------------------(')

SUB sub_Log(BYVAL v_bError AS LONG, v_sText AS WSTRING)
  LOCAL v_hFile AS LONG
  LOCAL v_lError AS LONG
  LOCAL v_sLogPath AS WSTRING
  LOCAL v_sTimestamp AS WSTRING
  v_sTimestamp = fn_sTimestamp
  v_sLogPath = PATHNAME$(PATH, v_gsExe) + "\AVIRscPtch_Log.csv"
  TRY
      OPEN v_sLogPath FOR APPEND AS # v_hFile
      PRINT # v_hFile, v_sTimestamp + "," + fn_sCSV(v_sText)
      CLOSE # v_hFile
      IF v_bError THEN MESSAGEBOX %HWND_DESKTOP, "Error during patching:" + $LF + v_sText, EXE.NAMEX$, %MB_ICONEXCLAMATION
  CATCH
      v_lError = ERR
      MESSAGEBOX %HWND_DESKTOP, _
        "Could not record message to the log file." + $LF + $LF + _
        "Timestamp:" + $LF + v_sTimestamp + $LF + $LF + _
        "Log Path:" + $LF + v_sLogPath + $LF + $LF + _
        "Error:" + ERROR$(v_lError) + $LF + $LF + _
        "Msg:" + $LF + v_sText, _
        EXE.NAMEX$, %MB_ICONEXCLAMATION
      IF v_hFile THEN CLOSE # v_hFile
  END TRY
END SUB

'----------------------------------------------------------------------------(')

FUNCTION fn_bIsAVI(BYVAL v_pData AS DWORD, BYVAL v_cbData AS DWORD) AS LONG
  IF v_pData = 0 THEN sub_Log 0, "pdata = 0" : EXIT FUNCTION
  IF v_cbData < 12 THEN sub_Log 0, "cbData < 12" : EXIT FUNCTION
  IF PEEK$(v_pData, 4) <> "RIFF" THEN sub_Log 0, "Not a RIFF" : EXIT FUNCTION
  IF PEEK$(v_pData + 8, 4) <> "AVI " THEN sub_Log 0, "Not an AVI" : EXIT FUNCTION
  FUNCTION = %TRUE
END FUNCTION

'----------------------------------------------------------------------------(')

FUNCTION fn_lEnumLangProc( _
      BYVAL v_hModule AS DWORD, _
      BYVAL v_lpType AS DWORD, _
      BYVAL v_lpName AS DWORD, _
      BYVAL v_wLang AS WORD, _
      BYVAL v_lParam AS LONG) AS LONG
  LOCAL v_bOK AS LONG
  LOCAL v_cbData AS DWORD
  LOCAL v_hData AS DWORD
  LOCAL v_hRes AS DWORD
  LOCAL v_lError AS LONG
  LOCAL v_pData AS DWORD
  LOCAL v_wzTypeAVI AS WSTRINGZ * 4
  ' FindResourceEx
  v_hRes = FINDRESOURCEEX(v_hModule, BYVAL %RT_RCDATA, BYVAL v_lpName, v_wLang)
  v_lError = GETLASTERROR
  IF v_hRes = 0 THEN
      sub_Log 0, "Error calling FindResourceEx: " + fn_sGetErrorText(v_lError)
      FUNCTION = %TRUE
      EXIT FUNCTION
  END IF
  v_cbData = SIZEOFRESOURCE(v_hModule, v_hRes)
  v_hData = LOADRESOURCE(v_hModule, v_hRes)
  v_pData = LOCKRESOURCE(v_hData)
  IF fn_bIsAVI(v_pData, v_cbData) THEN
      v_wzTypeAVI = "AVI"
      ' UpdateResource - Copy resource to new resource type
      v_bOK = UPDATERESOURCE(v_ghUpd, BYVAL VARPTR(v_wzTypeAVI), BYVAL v_lpName, v_wLang, BYVAL v_pData, v_cbData)
      v_lError = GETLASTERROR
      IF v_bOK THEN
        ' UpdateResource - Remove resource from old resource type
        v_bOK = UPDATERESOURCE(v_ghUpd, BYVAL %RT_RCDATA, BYVAL v_lpName, v_wLang, BYVAL %NULL, 0)
        v_lError = GETLASTERROR
        IF v_bOK = %FALSE THEN sub_Log 1, "Error calling UpdateResource (delete old): " + fn_sGetErrorText(v_lError)
      ELSE
        sub_Log 1, "Error calling UpdateResource (copy to new): " + fn_sGetErrorText(v_lError)
      END IF
  END IF
  FUNCTION = %TRUE
END FUNCTION

'----------------------------------------------------------------------------(')

FUNCTION fn_lEnumNameProc( _
      BYVAL v_hModule AS DWORD, _
      BYVAL v_lpType AS DWORD, _
      BYVAL v_lpName AS DWORD, _
      BYVAL v_lParam AS LONG) AS LONG
  ENUMRESOURCELANGUAGES(v_hModule, BYVAL %RT_RCDATA, BYVAL v_lpName, CODEPTR(fn_lEnumLangProc), 0)
  FUNCTION = %TRUE
END FUNCTION

'----------------------------------------------------------------------------(')

FUNCTION PBMAIN() AS LONG
  LOCAL v_bOK AS LONG
  LOCAL v_lError AS LONG
  LOCAL v_sCmd AS STRING
  LOCAL v_wzExe AS WSTRINGZ * %MAX_PATH
  v_sCmd = TRIM$(COMMAND$, ANY CHR$(32, 34))
  IF LEN(v_sCmd) THEN
      v_gsExe = v_sCmd
  ELSE
      sub_Log 1, "Please supply a module (DLL/EXE) path to patch"
      EXIT FUNCTION
  END IF
  IF ISFILE(v_gsExe) = %FALSE THEN
      sub_Log 1, "Module (DLL/EXE) path does not exist"
      EXIT FUNCTION
  END IF
  v_wzExe = v_gsExe
  sub_Log 0, "Attemping to patch module: " + $DQ + v_gsExe + $DQ
  v_ghMod = LOADLIBRARYEX(BYVAL VARPTR(v_wzExe), BYVAL %NULL, %LOAD_LIBRARY_AS_DATAFILE)
  v_lError = GETLASTERROR
  IF v_ghMod = 0 THEN
      sub_Log 1, "Error loading module: " + fn_sGetErrorText(v_lError)
      EXIT FUNCTION
  END IF
  ' BeginUpdateResource
  v_ghUpd = BEGINUPDATERESOURCE(BYVAL VARPTR(v_wzExe), %FALSE)
  v_lError = GETLASTERROR
  IF v_ghUpd = 0 THEN
      sub_Log 1, "Error calling BeginUpdateResource: " + fn_sGetErrorText(v_lError)
      FREELIBRARY v_ghMod
      EXIT FUNCTION
  END IF
  ' EnumResourceNames
  v_bOK = ENUMRESOURCENAMES(v_ghMod, BYVAL %RT_RCDATA, CODEPTR(fn_lEnumNameProc), 0)
  v_lError = GETLASTERROR
  IF v_bOK = %FALSE THEN
      sub_Log 1, "Error calling EnumResourceNames: " + fn_sGetErrorText(v_lError)
      FREELIBRARY v_ghMod
      EXIT FUNCTION
  END IF
  ' Release the module
  FREELIBRARY v_ghMod
  ' EndUpdateResource
  v_bOK = ENDUPDATERESOURCE(v_ghUpd, %FALSE)
  v_lError = GETLASTERROR
  IF v_bOK = %FALSE THEN
      sub_Log 1, "Error calling EndUpdateResource: " + fn_sGetErrorText(v_lError)
      EXIT FUNCTION
  END IF
  sub_Log 0, "Module patched"
END FUNCTION

Print this item

  Where is CAfxMp3.inc
Posted by: Owen_English - 27.12.2025, 02:48 - Forum: PowerBASIC for Windows - Replies (3)

Not quite sure where I got this chunk of code from but it includes CAfxMp3.inc which I don't have.
Have searched everywhere - Google mentions it but leads nowhere.
Anyone heard of or got a copy of this one please?

Print this item

  "Unread-Posts Sign" re-appears
Posted by: Albert Richheimer - 16.12.2025, 08:37 - Forum: Suggestions and discussion about PUMP - Replies (7)

Hi @all

Dale Yarker has pointed out that from time to time the "unread posts sign", a black disc, re-appears, although there are no new postings in the affected subforums.

Has anyone else noticed this strange phenomenon?

Cheers,
Albert

Print this item

  Posts here
Posted by: Dale Yarker - 25.11.2025, 16:54 - Forum: Suggestions and discussion about PUMP - Replies (2)

seemed to have stopped completely.
I still check a couple times a day. I suspect some others do too.
If you haven't switched to new PB forum, you can discuss or question here, and someone will see it.

Cheers,

Print this item

  How to run PB progs in Linux
Posted by: Mannish Bhandari - 19.10.2025, 22:27 - Forum: PowerBASIC for Windows - Replies (13)

I heard so many terrible stories about upgrading to Windows 11 I'm now interested to use Linux instead and I want to be able to run my PB 
progs in Linux.  how to do this ?

Print this item

  READ$/Data Slow
Posted by: Brent F Boshart - 11.10.2025, 00:55 - Forum: PowerBASIC for Windows - Replies (4)

I have some data that I want to keep embedded in the code instead of an external file.  This takes about 4 seconds to execute (the routines formatStarRA, formatStarDec and J2000Topo only account for about 0.3 seconds).  I could make each line (element) one string padding with spaces and then using mid$ to parse it out. That would be 2400 READ$ instead of 2400*11.   Any other suggestions to speed this up? 




FUNCTION DoubleStarLoad AS LONG
    LOCAL t AS LONG
    LOCAL tempRA, TempDec AS DOUBLE, dummy AS STRING

    FOR t= 0 TO 2399
        DoubleStarData(t).CST=READ$((t)*11+1)
        DoubleStarData(t).ObjName=READ$((t)*11+2)
        DoubleStarData(t).SAO=READ$((t)*11+3)
        tempRA=formatStarRA(READ$((t)*11+4))
        tempDec=formatStarDec(READ$((t)*11+5))
        J2000Topo(tempRA,tempDec)
        DoubleStarData(t).RA=tempRA
        DoubleStarData(t).Dec=tempDec
        DoubleStarData(t).Magnitude1=READ$(t*11+6)
        DoubleStarData(t).Magnitude2=READ$(t*11+7)
        DoubleStarData(t).Spectral=READ$(t*11+9)
        DoubleStarData(t).Distance=VAL(READ$(t*11+10))
        DoubleStarData(t).Separation=READ$(t*11+11)
    NEXT t

    DATA "Aqr","1 Aqr","126062","20:39:25","+00:29:11","5.27","12.3","7.03","K0III","71.48","65"
    DATA "Ari","1 Ari","74966","01:49:50","+22:15:45","16","17","1","M3.7+M4.2","","17.5"
    DATA "Ari","1 Ari","74966","01:50:09","+22:16:30","6.33","7.21","0.88","G3III","179.53","2.9"
    DATA "Boo","1 Boo","82942","13:40:40","+19:57:20","5.76","9.6","3.84","A1V","100.6","4.4"
    DATA "Cam","1 Cam","24672","04:32:02","+53:54:39","5.78","6.82","1.04","B0III","217.39","10.4"
    DATA "Del","1 Del","106172","20:30:18","+10:53:45","6.2","8.02","1.82","Be+B","227.79","0.9"
    DATA "Dra","1 Dra","15532","11:31:07","+69:24:00","14.3","14.8","0.5","","","1.2"
    ....

END FUNCTION

Print this item